[ < ] | [ > ] |  | [ << ] | [ Up ] | [ >> ] |  |  |  |  | [Top] | [Contents] | [Index] | [ ? ]

# 82. stats

[ < ] | [ > ] |  | [ << ] | [ Up ] | [ >> ] |  |  |  |  | [Top] | [Contents] | [Index] | [ ? ]

## 82.1 Introduction to stats

パッケージ `stats`は古典的な統計推定や仮説検定手続き一式を含みます。

これらの関数はすべて、母集団推定と意思決定のための必要な結果を含む `inference_result` Maximaオブジェクトを返します。

グローバル変数 `stats_numer`は、 結果を浮動小数点フォーマットで与えるか、シンボルと有理数のフォーマットで与えるかを制御します; デフォルト値は `true`で、結果を浮動小数点フォーマットで返します。

パッケージ `descriptive`はデータ構造(リストと行列)を操作するための いくつかのユーティリティを含みます; 例えば、部分サンプルを抽出するためのもの。 プレインテキストファイルからデータを読むためのパッケージ `numericalio`の使い方に関するいくつかの例も含みます。 詳細は `descriptive`と `numericalio`を参照してください。

パッケージ `stats`は、パッケージ `descriptive`, `distrib`, `inference_result`をロードします。

コメント、バグ、提案は、作者 'mario AT edu DOT xunta DOT es'にコンタクトしてください。

Categories: Statistical inference · Share packages · Package stats

[ < ] | [ > ] |  | [ << ] | [ Up ] | [ >> ] |  |  |  |  | [Top] | [Contents] | [Index] | [ ? ]

## 82.2 Functions and Variables for inference_result

関数: inference_result (title, values, numbers)

  statsの関数が返す型の `inference_result`オブジェクトを構成します。 引数 titleは手続き名の文字列です; valuesは形式 `symbol = value`の要素を持つリストであり、 numbersは、どの値がデフォルトで表示されるか示す 1から `length(values)`までの範囲の正の整数のリストです。

  例:

  これは長方形に関する結果を示す簡単な例です。 このオブジェクトのタイトルは文字列 `"Rectangle"`であり、 `'base`, `'height`, `'diagonal`, `'area`, `'perimeter`と指名された 5つの結果を格納しますが、 一番目、二番目、五番目と四番目だけが表示されます。 `'diagonal`はこのオブジェクトに格納されますが、表示されません; その値にアクセスするには関数 `take_inference`を利用してください。

      (%i1) load(inference_result)$
      (%i2) b: 3$ h: 2$
      (%i3) inference_result("Rectangle",
                              ['base=b,
                               'height=h,
                               'diagonal=sqrt(b^2+h^2),
                               'area=b*h,
                               'perimeter=2*(b+h)],
                              [1,2,5,4] );
                              |   Rectangle
                              |
                              |    base = 3
                              |
      (%o3)                   |   height = 2
                              |
                              | perimeter = 10
                              |
                              |    area = 6
      (%i4) take_inference('diagonal,%);
      (%o4)                        sqrt(13)

  `take_inference`も参照してください。

  Categories: Package stats

関数: inferencep (obj)

  objが `inference_result`オブジェクトか否かに依存して、 `true`か `false`を返します。

  Categories: Package stats

関数: items_inference (obj)

  objに格納された項目名のリストを返します。 objは `inference_result`オブジェクトでなければいけません。

  例:

  `inference_result`オブジェクトは `'pi`と `'e`と名付けられた2つの値を格納しますが、二番目だけが表示されます。 `items_inference`関数は、表示されるされないに関係なく、項目すべての名前を返します。

      (%i1) load(inference_result)$
      (%i2) inference_result("Hi", ['pi=%pi,'e=%e],[2]);
                                  |   Hi
      (%o2)                       |
                                  | e = %e
      (%i3) items_inference(%);
      (%o3)                        [pi, e]

  Categories: Package stats

関数: take_inference
`take_inference` (n, obj)
`take_inference` (name, obj)
`take_inference` (list, obj)

  もし nが正の整数なら、 objに格納された n番目の値を返します。 もし nameが項目名なら、そう名付けられた項目を返します。 もし一番目の引数が数やシンボルのリストなら、 関数 `take_inference`は対応する結果のリストを返します。

  例:

  ある `inference_result`オブジェクトが与えられたとして、 それに格納されたある情報を抽出するために関数 `take_inference`がコールされます。

      (%i1) load(inference_result)$
      (%i2) b: 3$ h: 2$
      (%i3) sol: inference_result("Rectangle",
                                  ['base=b,
                                   'height=h,
                                   'diagonal=sqrt(b^2+h^2),
                                   'area=b*h,
                                   'perimeter=2*(b+h)],
                                  [1,2,5,4] );
                              |   Rectangle
                              |
                              |    base = 3
                              |
      (%o3)                   |   height = 2
                              |
                              | perimeter = 10
                              |
                              |    area = 6
      (%i4) take_inference('base,sol);
      (%o4)                           3
      (%i5) take_inference(5,sol);
      (%o5)                          10
      (%i6) take_inference([1,'diagonal],sol);
      (%o6)                     [3, sqrt(13)]
      (%i7) take_inference(items_inference(sol),sol);
      (%o7)                [3, 2, sqrt(13), 6, 10]

  `inference_result`と `take_inference`も参照してください。

  Categories: Package stats

[ < ] | [ > ] |  | [ << ] | [ Up ] | [ >> ] |  |  |  |  | [Top] | [Contents] | [Index] | [ ? ]

## 82.3 Functions and Variables for stats

オプション変数: stats_numer

  デフォルト値: `true`

  もし `stats_numer`が `true`なら、 推定統計的関数は浮動小数点数で結果を返します。 もし `false`なら、 結果は記号と有理フォーマットで与えられます。

  Categories: Package stats · Numerical evaluation

関数: test_mean
`test_mean` (x)
`test_mean` (x, options ...)

  これは平均t検定です。 引数 xは1次元標本を含むリストか列行列です。 もしオプション `'asymptotic`が `true`なら、 中心極限定理に基づいた漸近検定も実行します。

  オプション:

  - `'mean`, デフォルト `0`, はチェックされる平均値です。
  - `'alternative`, デフォルト `'twosided`, は対立仮説です; 有効な値は次の通りです: `'twosided`, `'greater`, `'less`。
  - `'dev`, デフォルト `'unknown`, は既知の時の標準偏差値です; 有効な値は次の通りです: `'unknown`か正の式。
  - `'conflevel`, デフォルト `95/100`, は信頼区間の信頼度です; (0,1)内の値を取る式でなければいけません。
  - `'asymptotic`, デフォルト `false`, は正確確率t検定か、 中心極限定理に基づいた漸近検定かどちらを実行するかを示します; 有効な値は `true`と `false`です。

  関数 `test_mean`の出力は 以下の結果を示す`inference_result` Maximaオブジェクトです:

  1. `'mean_estimate`: 標本平均。
  2. `'conf_level`: ユーザーが選択した信頼度。
  3. `'conf_interval`: 母平均の信頼度。
  4. `'method`: 推定手続き。
  5. `'hypotheses`: 検定される帰無と対立仮説。
  6. `'statistic`: 帰無仮説を検定するために使われる標本統計の値。
  7. `'distribution`: パラメータと合わせて、標本統計分布。
  8. `'p_value`: 検定のp値

  例:

  未知の分散で正確確率 t検定を実行します。 片側対立 H_1: mean<50に対して 帰無仮説は H_0: mean=50です; 結果に従うと、p値が大きすぎ、 H_0を却下する証拠がありません。

      (%i1) load("stats")$
      (%i2) data: [78,64,35,45,45,75,43,74,42,42]$
      (%i3) test_mean(data,'conflevel=0.9,'alternative='less,'mean=50);
                |                 MEAN TEST
                |
                |            mean_estimate = 54.3
                |
                |              conf_level = 0.9
                |
                | conf_interval = [minf, 61.51314273502712]
                |
      (%o3)     |  method = Exact t-test. Unknown variance.
                |
                | hypotheses = H0: mean = 50 , H1: mean < 50
                |
                |       statistic = .8244705235071678
                |
                |       distribution = [student_t, 9]
                |
                |        p_value = .7845100411786889

  今回、Maximaは 中心極限定理に基づく漸近検定を実行します。 両側対立 H_1: not equal(mean, 50)に対して 帰無仮説は H_0: equal(mean, 50)です; 結果に従うと、 p値は非常に小さく、 対立 H_1を指示して、H_0は却下すべきです。 . Note that, as indicated by the `Method`成分が示すように、 この手続きは多くの標本に適用すべきです。

      (%i1) load("stats")$
      (%i2) test_mean([36,118,52,87,35,256,56,178,57,57,89,34,25,98,35,
                    98,41,45,198,54,79,63,35,45,44,75,42,75,45,45,
                    45,51,123,54,151],
                    'asymptotic=true,'mean=50);
                |                       MEAN TEST
                |
                |           mean_estimate = 74.88571428571429
                |
                |                   conf_level = 0.95
                |
                | conf_interval = [57.72848600856194, 92.04294256286663]
                |
      (%o2)     |    method = Large sample z-test. Unknown variance.
                |
                |       hypotheses = H0: mean = 50 , H1: mean # 50
                |
                |             statistic = 2.842831192874313
                |
                |             distribution = [normal, 0, 1]
                |
                |             p_value = .004471474652002261

  Categories: Package stats

関数: test_means_difference
`test_means_difference` (x1, x2)
`test_means_difference` (x1, x2, options ...)

  これは2つの標本の平均の差 t検定です。 引数 x1と x2は2つの独立標本を含むリストか列行列です。 異なる未知の分散の場合 (以下のオプション `'dev1`, `'dev2`, `'varequal`を参照してください)、 自由度の次数はWelch近似を使って計算されます。 もしオプション `'asymptotic`が `true`に設定されているなら 中心極限定理に基づく漸近検定も実行します。

  オプション:

  - `'alternative`, デフォルト `'twosided`, は対立仮説です; 有効な値は次の通りです: `'twosided`, `'greater`, `'less`。
  - `'dev1`, デフォルト `'unknown`, 既知の時、これはx1標本の標準偏差値です; 有効な値は次の通りです: `'unknown`もしくは正の式。
  - `'dev2`, デフォルト `'unknown`, 既知の時、これはx2標本の標準偏差値です; 有効な値は次の通りです: `'unknown`もしくは正の式。
  - `'varequal`, デフォルト `false`, 分散を等しいと考えるか等しくないと考えるか; このオプションは`'dev1`と `'dev2`の両方もしくはいずれかが `'unknown`の時だけ 有効です。
  - `'conflevel`, デフォルト `95/100`, 信頼区間の信頼度; (0,1)内の値を取る式でなければいけません。
  - `'asymptotic`, デフォルト `false`, 正確確率 t検定か 中心極限定理に基づく漸近検定どちらを実行するかを示します; 有効な値は `true`と `false`です。

  関数 `test_means_difference`の出力は 以下の結果を示す`inference_result` Maximaオブジェクトです:

  1. `'diff_estimate`: 平均差推定。
  2. `'conf_level`: ユーザーが選択した信頼度。
  3. `'conf_interval`: 平均差の信頼区間。
  4. `'method`: 推定手続き。
  5. `'hypotheses`: 検定される帰無、対立仮説。
  6. `'statistic`: 帰無仮説を検定するのに使われる標本統計値
  7. `'distribution`: パラメータを伴う標本統計分布。
  8. `'p_value`: 検定のp値。

  例:

  母平均 m_1と m_2で対立 H_1: m_1>m_2に対して 2つの小さな標本 x yで平均が等しいか検定します; 分散は未知で異なると仮定されます。

      (%i1) load("stats")$
      (%i2) x: [20.4,62.5,61.3,44.2,11.1,23.7]$
      (%i3) y: [1.2,6.9,38.7,20.4,17.2]$
      (%i4) test_means_difference(x,y,'alternative='greater);
                  |              DIFFERENCE OF MEANS TEST
                  |
                  |         diff_estimate = 20.31999999999999
                  |
                  |                 conf_level = 0.95
                  |
                  |    conf_interval = [- .04597417812882298, inf]
                  |
      (%o4)       |        method = Exact t-test. Welch approx.
                  |
                  | hypotheses = H0: mean1 = mean2 , H1: mean1 > mean2
                  |
                  |           statistic = 1.838004300728477
                  |
                  |    distribution = [student_t, 8.62758740184604]
                  |
                  |            p_value = .05032746527991905

  前と同じ検定、 しかし今回は分散が等しいと仮定されます。

      (%i1) load("stats")$
      (%i2) x: [20.4,62.5,61.3,44.2,11.1,23.7]$
      (%i3) y: matrix([1.2],[6.9],[38.7],[20.4],[17.2])$
      (%i4) test_means_difference(x,y,'alternative='greater,
                                                       'varequal=true);
                  |              DIFFERENCE OF MEANS TEST
                  |
                  |         diff_estimate = 20.31999999999999
                  |
                  |                 conf_level = 0.95
                  |
                  |     conf_interval = [- .7722627696897568, inf]
                  |
      (%o4)       |   method = Exact t-test. Unknown equal variances
                  |
                  | hypotheses = H0: mean1 = mean2 , H1: mean1 > mean2
                  |
                  |           statistic = 1.765996124515009
                  |
                  |           distribution = [student_t, 9]
                  |
                  |            p_value = .05560320992529344

  Categories: Package stats

関数: test_variance
`test_variance` (x)
`test_variance` (x, options, ...)

  これは分散 chi^2検定です。 引数 xは 正規母集団から取られた1次元標本を含む リストか列行列です。

  オプション:

  - `'mean`, デフォルト `'unknown`, は、既知の時、母平均です。
  - `'alternative`, デフォルト `'twosided`, 対立仮説です; 有効な値は次の通りです: `'twosided`, `'greater`, `'less`.
  - `'variance`, デフォルト `1`, これはチェックされる分散値(正)です。
  - `'conflevel`, デフォルト `95/100`, 信頼区間の信頼度; (0,1)内の値を取る式でなければいけません。

  関数 `test_variance`の出力は 以下の結果を示す`inference_result` Maximaオブジェクトです:

  1. `'var_estimate`: 標本分散。
  2. `'conf_level`: ユーザーが選択した信頼度。
  3. `'conf_interval`: 母分散の信頼区間。
  4. `'method`: 推定手続き。
  5. `'hypotheses`: 検定される帰無、対立仮説。
  6. `'statistic`: 帰無仮説を検定するのに使う標本統計値。
  7. `'distribution`: パラメータを伴う標本統計分布。
  8. `'p_value`: 検定の p値。

  例:

  平均が未知の母集団の分散が200以上か検定します。

      (%i1) load("stats")$
      (%i2) x: [203,229,215,220,223,233,208,228,209]$
      (%i3) test_variance(x,'alternative='greater,'variance=200);
                   |                  VARIANCE TEST
                   |
                   |              var_estimate = 110.75
                   |
                   |                conf_level = 0.95
                   |
                   |     conf_interval = [57.13433376937479, inf]
                   |
      (%o3)        | method = Variance Chi-square test. Unknown mean.
                   |
                   |    hypotheses = H0: var = 200 , H1: var > 200
                   |
                   |                 statistic = 4.43
                   |
                   |             distribution = [chi2, 8]
                   |
                   |           p_value = .8163948512777689

  Categories: Package stats

関数: test_variance_ratio
`test_variance_ratio` (x1, x2)
`test_variance_ratio` (x1, x2, options ...)

  これは2つの正規母集団の分散比 F検定です。 引数 x1と x2は 2つの独立標本を含むリストか列行列です。

  オプション:

  - `'alternative`, デフォルト `'twosided`, は対立仮説です; 有効な値は次の通りです: `'twosided`, `'greater`, `'less`.
  - `'mean1`, デフォルト `'unknown`, 既知の時、これはx1が取られた母集団の平均です。
  - `'mean2`, デフォルト `'unknown`, 既知の時、これはx2が取られた母集団の平均です。
  - `'conflevel`, デフォルト `95/100`, 比の信頼区間の信頼度; (0,1)内の値を取る式でなければいけません。

  関数 `test_variance_ratio`の出力は 以下の結果を示す`inference_result` Maximaオブジェクトです:

  1. `'ratio_estimate`: 標本分散比。
  2. `'conf_level`: ユーザーが選択した信頼度。
  3. `'conf_interval`: 分散比の信頼区間。
  4. `'method`: 推定手続き。
  5. `'hypotheses`: 検定される帰無、対立仮説。
  6. `'statistic`: 帰無仮説を検定するのに使われる標本統計値。
  7. `'distribution`: パラメータを伴う標本統計分布。
  8. `'p_value`: 検定のp値。

  例:

  前者が後者より大きいという対立仮説に対して、 2つの正規母集団の分散の等しさが

      (%i1) load("stats")$
      (%i2) x: [20.4,62.5,61.3,44.2,11.1,23.7]$
      (%i3) y: [1.2,6.9,38.7,20.4,17.2]$
      (%i4) test_variance_ratio(x,y,'alternative='greater);
                    |              VARIANCE RATIO TEST
                    |
                    |       ratio_estimate = 2.316933391522034
                    |
                    |               conf_level = 0.95
                    |
                    |    conf_interval = [.3703504689507268, inf]
                    |
      (%o4)         | method = Variance ratio F-test. Unknown means.
                    |
                    | hypotheses = H0: var1 = var2 , H1: var1 > var2
                    |
                    |         statistic = 2.316933391522034
                    |
                    |            distribution = [f, 5, 4]
                    |
                    |          p_value = .2179269692254457

  Categories: Package stats

関数: test_proportion
`test_proportion` (x, n)
`test_proportion` (x, n, options ...)

  出現率推定。 引数 xは 未知の確率でのBernoulli実験のn回試行での成功回数です。

  オプション:

  - `'proportion`, デフォルト `1/2`, はチェックされる出現率の値です。
  - `'alternative`, デフォルト `'twosided`, は対立仮説です; 有効な値は次の通りです: `'twosided`, `'greater`, `'less`.
  - `'conflevel`, デフォルト `95/100`, 比の信頼区間の信頼度; (0,1)内の値を取る式でなければいけません。
  - `'asymptotic`, デフォルト `false`, 二項分布に基づく正確確率 t検定か 中心極限定理に基づく漸近検定どちらを実行するかを示します; 有効な値は `true`と `false`です。
  - `'correct`, デフォルト `true`, Yates補正が適用されるかどうかを示します。

  The output of function 関数 `test_proportion`の出力は 以下の結果を示す `inference_result` Maximaオブジェクトです:

  1. `'sample_proportion`: 標本出現率。
  2. `'conf_level`: ユーザーが選択した信頼度。
  3. `'conf_interval`: 出現率のWilson信頼区間。
  4. `'method`: 推定手続き。
  5. `'hypotheses`: 検定される帰無、対立仮説。
  6. `'statistic`: 帰無仮説を検定するのに使われる標本統計値。
  7. `'distribution`: パラメータを伴う標本統計分布。
  8. `'p_value`: 検定のp値。

  例:

  正確確率検定を実行します。 片側対立 H_1: p<1/2に対して、 帰無仮説は H_0: p=1/2です。

      (%i1) load("stats")$
      (%i2) test_proportion(45, 103, alternative = less);
               |            PROPORTION TEST
               |
               | sample_proportion = .4368932038834951
               |
               |           conf_level = 0.95
               |
               | conf_interval = [0, 0.522714149150231]
               |
      (%o2)    |     method = Exact binomial test.
               |
               | hypotheses = H0: p = 0.5 , H1: p < 0.5
               |
               |             statistic = 45
               |
               |  distribution = [binomial, 103, 0.5]
               |
               |      p_value = .1184509388901454

  両側漸近検定。信頼度は99/100です。

      (%i1) load("stats")$
      (%i2) fpprintprec:7$
      (%i3) test_proportion(45, 103,
                        conflevel = 99/100, asymptotic=true);
            |                 PROPORTION TEST
            |
            |           sample_proportion = .43689
            |
            |                conf_level = 0.99
            |
            |        conf_interval = [.31422, .56749]
            |
      (%o3) | method = Asympthotic test with Yates correction.
            |
            |     hypotheses = H0: p = 0.5 , H1: p # 0.5
            |
            |               statistic = .43689
            |
            |      distribution = [normal, 0.5, .048872]
            |
            |                p_value = .19662

  Categories: Package stats

関数: test_proportions_difference
`test_proportions_difference` (x1, n1, x2, n2)
`test_proportions_difference` (x1, n1, x2, n2, options …)

  2つの出現率の差の推定。 引数 x1は 一番目の母集団でのBernoulli実験の n1回の試行での成功回数であり、 x2と n2は 二番目の母集団での対応する値です。 標本は独立で、検定は漸近です。

  オプション:

  - `'alternative`, デフォルト `'twosided`, は対立仮説です; 有効な値は次の通りです: `'twosided` (`p1 # p2`), `'greater` (`p1 > p2`), `'less` (`p1 < p2`).
  - `'conflevel`, デフォルト `95/100`, 比の信頼区間の信頼度; (0,1)内の値を取る式でなければいけません。
  - `'correct`, デフォルト `true`, はYates補正が適用されるかどうかを示します。

  関数 `test_proportions_difference`の出力は 以下の結果を示す `inference_result` Maximaオブジェクトです:

  1. `'proportions`: 2つの標本出現率のリスト。
  2. `'conf_level`: ユーザーが選択した信頼度。
  3. `'conf_interval`: 出現率の差 `p1 - p2`の信頼区間。
  4. `'method`: 推定手続きと 標本サイズのいずれかが10より小さい場合の警告メッセージ
  5. `'hypotheses`: 検定される帰無、対立仮説。
  6. `'statistic`: 帰無仮説を検定するのに使われる標本統計値。
  7. `'distribution`: パラメータを伴う標本統計分布。
  8. `'p_value`: 検定のp値。

  例:

  機械が250個のうち、10個の欠陥製品を製造しました。 その機械は、ある保守作業のあと、 150個のうち、4個の欠陥製品を製造しました。 機械が改善したか知るために、 対立 `H0:p1>p2`に対して 帰無仮説 `H0:p1=p2`を検定します。 ここで、 `p1`と `p2`は 保守の前と後で製造された製品が欠陥である確率です。 p値に従うと、対立を受け入れる十分な証拠はありません。

      (%i1) load("stats")$
      (%i2) fpprintprec:7$
      (%i3) test_proportions_difference(10, 250, 4, 150,
                                      alternative = greater);
            |       DIFFERENCE OF PROPORTIONS TEST
            |
            |       proportions = [0.04, .02666667]
            |
            |              conf_level = 0.95
            |
            |      conf_interval = [- .02172761, 1]
            |
      (%o3) | method = Asymptotic test. Yates correction.
            |
            |   hypotheses = H0: p1 = p2 , H1: p1 > p2
            |
            |            statistic = .01333333
            |
            |    distribution = [normal, 0, .01898069]
            |
            |             p_value = .2411936

  データが未知の時の漸近正規分布の正確確率標準偏差。

      (%i1) load("stats")$
      (%i2) stats_numer: false$
      (%i3) sol: test_proportions_difference(x1,n1,x2,n2)$
      (%i4) last(take_inference('distribution,sol));
                     1    1                  x2 + x1
                    (-- + --) (x2 + x1) (1 - -------)
                     n2   n1                 n2 + n1
      (%o4)    sqrt(---------------------------------)
                                 n2 + n1

  Categories: Package stats

関数: test_sign
`test_sign` (x)
`test_sign` (x, options …)

  これは連続母集団のメジアンに関するノンパラメトリック符号検定です。 引数 xは1次元標本を含むリストか列行列です。

  オプション:

  - `'alternative`, デフォルト `'twosided`, は対立仮説です; 有効な値は次の通りです: `'twosided`, `'greater`, `'less`.
  - `'median`, デフォルト `0`, はチェックされるメジアン値です。

  関数 `test_sign`の出力は 以下の結果を示す `inference_result` Maximaオブジェクトです:

  1. `'med_estimate`: 標本メジアン。
  2. `'method`: 推定手続き。
  3. `'hypotheses`: 検定される帰無、対立仮説。
  4. `'statistic`: 帰無仮説を検定するのに使われる標本統計値。
  5. `'distribution`: パラメータを伴う標本統計分布。
  6. `'p_value`: 検定のp値。

  例:

  対立 H_1: median > 6に対して、 標本が採られた母集団がメジアン6を持つかどうかチェックします。

      (%i1) load("stats")$
      (%i2) x: [2,0.1,7,1.8,4,2.3,5.6,7.4,5.1,6.1,6]$
      (%i3) test_sign(x,'median=6,'alternative='greater);
                     |                  SIGN TEST
                     |
                     |              med_estimate = 5.1
                     |
                     |      method = Non parametric sign test.
                     |
      (%o3)          | hypotheses = H0: median = 6 , H1: median > 6
                     |
                     |                statistic = 7
                     |
                     |      distribution = [binomial, 10, 0.5]
                     |
                     |         p_value = .05468749999999989

  Categories: Package stats

関数: test_signed_rank
`test_signed_rank` (x)
`test_signed_rank` (x, options …)

  これは 連続母集団のメジアンに関する推定を行う Wilcoxonの符号順位検定です。 引数 xは 1次元標本を含む リストか列行列です。 もし標本サイズが20より大きいか、複数の零すなわち引き分けがあれば、 正規近似を実行します

  `pdf_rank_test`と `cdf_rank_test`も参照してください。

  オプション:

  - `'median`, デフォルト `0`, はチェックされるメジアン値です。
  - `'alternative`, デフォルト `'twosided`, は対立仮説です; 有効な値は次の通りです: `'twosided`, `'greater` and `'less`.

  関数 `test_signed_rank`の出力は 以下の結果を持つ `inference_result` Maximaオブジェクトです:

  1. `'med_estimate`: 標本メジアン。
  2. `'method`: 推定手続き。
  3. `'hypotheses`: 検定される帰無、対立仮説。
  4. `'statistic`: 帰無仮説を検定するのに使われる標本統計値。
  5. `'distribution`: パラメータを伴う標本統計分布。
  6. `'p_value`: 検定のp値。

  例:

  対立 H_1: median > 15に対して 帰無仮説 H_0: median = 15をチェックします。 引き分けがないので、これは正確確率検定です。

      (%i1) load("stats")$
      (%i2) x: [17.1,15.9,13.7,13.4,15.5,17.6]$
      (%i3) test_signed_rank(x,median=15,alternative=greater);
                       |             SIGNED RANK TEST
                       |
                       |           med_estimate = 15.7
                       |
                       |           method = Exact test
                       |
      (%o3)            | hypotheses = H0: med = 15 , H1: med > 15
                       |
                       |              statistic = 14
                       |
                       |     distribution = [signed_rank, 6]
                       |
                       |            p_value = 0.28125

  Checks the null hypothesis H_0: equal(median, 2.5) against the alternative H_1: not equal(median, 2.5). This is an approximated test, since there are ties.

      (%i1) load("stats")$
      (%i2) y:[1.9,2.3,2.6,1.9,1.6,3.3,4.2,4,2.4,2.9,1.5,3,2.9,4.2,3.1]$
      (%i3) test_signed_rank(y,median=2.5);
                   |                 SIGNED RANK TEST
                   |
                   |                med_estimate = 2.9
                   |
                   |          method = Asymptotic test. Ties
                   |
      (%o3)        |    hypotheses = H0: med = 2.5 , H1: med # 2.5
                   |
                   |                 statistic = 76.5
                   |
                   | distribution = [normal, 60.5, 17.58195097251724]
                   |
                   |           p_value = .3628097734643669

  Categories: Package stats

関数: test_rank_sum
`test_rank_sum` (x1, x2)
`test_rank_sum` (x1, x2, option)

  これは 2つの連続母集団のメジアンを比較するWilcoxon-Mann-Whitney検定です。 最初の2つの引数 x1と x2は 2つの独立標本のデータを持つリストか列行列です。 もし標本サイズのいずれかが10より大きいか、 引き分けがあるなら、 正規近似を実行します。

  オプション:

  - `'alternative`, デフォルト `'twosided`, は対立仮説です; 有効な値は次の通りです: `'twosided`, `'greater` and `'less`.

  The output of function 関数 `test_rank_sum`の出力は 以下の結果を持つ `inference_result` Maximaオブジェクトです:

  1. `'method`: 推定手続き。
  2. `'hypotheses`: 検定される帰無、対立仮説。
  3. `'statistic`: 帰無仮説を検定するのに使われる標本統計値。
  4. `'distribution`: パラメータを伴う標本統計分布。
  5. `'p_value`: 検定のp値。

  例:

  母集団が似たメジアンを持つかチェックします。 標本サイズは小さく、正確確率検定がされます。

      (%i1) load("stats")$
      (%i2) x:[12,15,17,38,42,10,23,35,28]$
      (%i3) y:[21,18,25,14,52,65,40,43]$
      (%i4) test_rank_sum(x,y);
                    |                 RANK SUM TEST
                    |
                    |              method = Exact test
                    |
                    | hypotheses = H0: med1 = med2 , H1: med1 # med2
      (%o4)         |
                    |                 statistic = 22
                    |
                    |        distribution = [rank_sum, 9, 8]
                    |
                    |          p_value = .1995886466474702

  次は、 より大きな標本で引き分けを含み、 手続きは正規近似をします。 対立仮説は H_1: median1 < median2です。

      (%i1) load("stats")$
      (%i2) x: [39,42,35,13,10,23,15,20,17,27]$
      (%i3) y: [20,52,66,19,41,32,44,25,14,39,43,35,19,56,27,15]$
      (%i4) test_rank_sum(x,y,'alternative='less);
                   |                  RANK SUM TEST
                   |
                   |          method = Asymptotic test. Ties
                   |
                   |  hypotheses = H0: med1 = med2 , H1: med1 < med2
      (%o4)        |
                   |                 statistic = 48.5
                   |
                   | distribution = [normal, 79.5, 18.95419580097078]
                   |
                   |           p_value = .05096985666598441

  Categories: Package stats

関数: test_normality (x)

  正規性のShapiro-Wilk検定。 引数 xは 数のリストであり、 標本サイズは2より大きく、5000以下でなければいけません。 そうでないなら、関数 `test_normality`はエラーメッセージをシグナルします。

  参考文献:

  [1] Algorithm AS R94, Applied Statistics (1995), vol.44, no.4, 547-551

  関数 `test_normality`の出力は 以下の結果を持つ `inference_result` Maximaオブジェクトです:

  1. `'statistic`: W統計値
  2. `'p_value`: 正規仮定のp値。

  例:

  サイズ9の標本に基づいて母集団の正規性をチェックします。

      (%i1) load("stats")$
      (%i2) x:[12,15,17,38,42,10,23,35,28]$
      (%i3) test_normality(x);
                             |      SHAPIRO - WILK TEST
                             |
      (%o3)                  | statistic = .9251055695162436
                             |
                             |  p_value = .4361763918860381

  Categories: Package stats

関数: linear_regression
`linear_regression` (x)
`linear_regression` (x option)

  重回帰 y_i = b0 + b1*x_1i + b2*x_2i + ... + bk*x_ki + u_i。 ここで u_iは N(0,sigma)個の独立確率変数です。 引数 xは複数の列を持つ行列でなければいけません。 最後の列は応答 (y_i)とみなされます。

  オプション:

  - `'conflevel`, デフォルト `95/100`, 比の信頼区間の信頼度; (0,1)内の値を取る式でなければいけません。

  関数 `linear_regression`の出力は 以下の結果を持つ `inference_result` Maximaオブジェクトです:

  1. `'b_estimation`: 回帰係数推定。
  2. `'b_covariances`: 回帰係数推定の共分散行列。
  3. `b_conf_int`: 回帰係数の信頼区間。
  4. `b_statistics`: 係数テストの統計。
  5. `b_p_values`: 係数テストのp値。
  6. `b_distribution`: 係数テストの確率分布。
  7. `v_estimation`: 不偏分散推定量。
  8. `v_conf_int`: 分散信頼区間。
  9. `v_distribution`: 分散テストの確率分布。
  10. `residuals`: 残差。
  11. `adc`: 調整済み決定係数。
  12. `aic`: 赤池情報量規準。
  13. `bic`: Bayes情報量規準。

  上の項目 1, 4, 5, 6, 7, 8, 9, 11だけがこの順で、デフォルトで表示されます。 残りはユーザーが関数 `items_inference`と `take_inference`を利用するまで 隠されたままです。

  例:

  線形モデルの三変量標本へのフィッティング。 最後の列は応答 (y_i)と見なされます。

      (%i2) load("stats")$
      (%i3) X:matrix(
          [58,111,64],[84,131,78],[78,158,83],
          [81,147,88],[82,121,89],[102,165,99],
          [85,174,101],[102,169,102])$
      (%i4) fpprintprec: 4$
      (%i5) res: linear_regression(X);
                   |       LINEAR REGRESSION MODEL
                   |
                   | b_estimation = [9.054, .5203, .2397]
                   |
                   | b_statistics = [.6051, 2.246, 1.74]
                   |
                   | b_p_values = [.5715, .07466, .1423]
                   |
      (%o5)        |   b_distribution = [student_t, 5]
                   |
                   |         v_estimation = 35.27
                   |
                   |     v_conf_int = [13.74, 212.2]
                   |
                   |      v_distribution = [chi2, 5]
                   |
                   |             adc = .7922
      (%i6) items_inference(res);
      (%o6) [b_estimation, b_covariances, b_conf_int, b_statistics,
      b_p_values, b_distribution, v_estimation, v_conf_int,
      v_distribution, residuals, adc, aic, bic]
      (%i7) take_inference('b_covariances, res);
                        [  223.9    - 1.12   - .8532  ]
                        [                             ]
      (%o7)             [ - 1.12    .05367   - .02305 ]
                        [                             ]
                        [ - .8532  - .02305   .01898  ]
      (%i8) take_inference('bic, res);
      (%o8)                          30.98
      (%i9) load("draw")$
      (%i10) draw2d(
          points_joined = true,
          grid = true,
          points(take_inference('residuals, res)) )$

  Categories: Package stats · Statistical estimation

[ < ] | [ > ] |  | [ << ] | [ Up ] | [ >> ] |  |  |  |  | [Top] | [Contents] | [Index] | [ ? ]

## 82.4 Functions and Variables for special distributions

関数: pdf_signed_rank (x, n)

  符号順位統計の正確確率分布の確率密度関数。 引数 xは実数であり、 nは正の整数です。

  `test_signed_rank`も参照してください。

  Categories: Package stats

関数: cdf_signed_rank (x, n)

  符号順位統計の正確確率分布の累積密度関数。 引数 xは実数であり、 nは正の整数です。

  `test_signed_rank`も参照してください。

  Categories: Package stats

関数: pdf_rank_sum (x, n, m)

  順位和統計の正確確率分布の確率密度関数。 引数 xは実数であり、 nと mはともに正の整数です。

  `test_rank_sum`も参照してください。

  Categories: Package stats

関数: cdf_rank_sum (x, n, m)

  順位和統計の正確確率分布の累積密度関数。 引数 xは実数であり、 nと mはともに正の整数です。

  `test_rank_sum`も参照してください。

  Categories: Package stats

[ << ] | [ >> ] |  |  |  |  |  | [Top] | [Contents] | [Index] | [ ? ]

This document was generated by 市川雄二 on June, 5 2017 using texi2html 1.76.