# Maintainer: Antonio Rojas <arojas@archlinux,org>

pkgname=krita
pkgver=6.0.0beta1
_pkgver=${pkgver/beta/-beta}
pkgrel=1
pkgdesc='Edit and paint images'
arch=(x86_64)
url='https://krita.org'
license=(GPL3)
depends=(exiv2
         ffmpeg
         fftw
         fontconfig
         freetype2
         fribidi
         gcc-libs
         giflib
         glibc
         gsl
         harfbuzz
         imath
         kcolorscheme
         kcompletion
         kconfig
         kcoreaddons
         kcrash
         kguiaddons
         ki18n
         kitemviews
         kwidgetsaddons
         lcms2
         libjpeg-turbo
         libkdcraw
         libpng
         libtiff
         libunibreak
         libwebp
         libx11
         libxkbcommon
         mlt
         opencolorio
         openexr
         openjpeg2
         qt6-5compat
         qt6-base
         qt6-declarative
         qt6-svg
         quazip-qt6
         wayland
         zlib)
makedepends=(boost
             eigen
             extra-cmake-modules
             immer
             kseexpr
             lager
             libheif
             libjxl
             libmypaint
             poppler-qt6
             python-pyqt6
             qt6-tools
             sip
             xsimd
             zug)
optdepends=('kimageformats: PSD support'
            'krita-plugin-gmic: GMic plugin'
            'kseexpr: SeExpr generator layer'
            'libheif: HEIF filter'
            'libjxl: JPEG-XL filter'
            'libmypaint: support for MyPaint brushes'
            'poppler-qt6: PDF filter'
            'python-pyqt6: for the Python plugins')
source=(https://download.kde.org/unstable/krita/$_pkgver/$pkgname-$_pkgver.tar.gz{,.sig}
        unused-dependencies.patch)
sha256sums=('1bde1abee987013ec96cc267eb8452eb9e5c7512d4ddb41882b9302d64620207'
            'SKIP'
            '1ea90e92567a96d9c8d3a5d27a9b9db5e4302796e89cec2163419beb94dfcf04')
validpgpkeys=('05D00A8B73A686789E0A156858B9596C722EA3BD'  # Boudewijn Rempt <foundation@krita.org>
              'E9FB29E74ADEACC5E3035B8AB69EB4CF7468332F'  # Dmitry Kazakov (main key) <dimula73@gmail.com>
              '064182440C674D9F8D0F6F8B4DA79EDA231C852B') # Stichting Krita Foundation <foundation@krita.org>

prepare() {
  patch -d $pkgname-$_pkgver -p1 < unused-dependencies.patch
}

build() {
  cmake -B build -S $pkgname-$_pkgver \
    -DBUILD_KRITA_QT_DESIGNER_PLUGINS=ON \
    -DBUILD_TESTING=OFF \
    -DBUILD_WITH_QT6=ON
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}
